Нашел вот такое решение:

pushd ..
set fullpath=%CD%
cd ..
for /d %%D in (*) do if "%%~fD"=="%fullpath%" set parent=%%D%
popd

echo Parent folder: "%parent%"

Вопрос: существует ли более простое и изящное?

Здравствуйте, wildwind, Вы писали:

W>Вопрос: существует ли более простое и изящное?

Встречный вопрос: чем не устроило %CD%\.. ?

Здравствуйте, Кодт, Вы писали:

К>Встречный вопрос: чем не устроило %CD%\.. ?

Наверное я плохо объяснил. Пусть текущая папка C:\One\Two\Three\I-am-here. Мне нужно получить "Three".

Здравствуйте, wildwind, Вы писали:

W>Наверное я плохо объяснил. Пусть текущая папка C:\One\Two\Three\I-am-here. Мне нужно получить "Three".

Чисто на обработке строк, безо всяких экскурсов по файловой системе:

@echo off

:: на всякий случай, вдруг эти режимы выключены
setlocal enableextensions enabledelayedexpansion

set s=%cd%
echo fullpath='%s%'

:: разобъём строку на имена каталогов (по \), для этого нам нужно эскейпить настоящие пробелы
:: в качестве эскейпа используем $
:: 1) эскейпим собственно $ (заменяя его на $$)
set s=%s:$=$$%
:: 2) эскейпим пробелы (заменяя на $_)
set s=%s: =$_%
:: 3) наконец, разбиваем строку на токены
set s=%s:\= %
echo after preprocessing '%s%'

:: пробежимся по токенам
echo iterating...
for %%t in (%s%) do (
  set parent=!last!
  set last=%%t
  echo parent='!parent!' last='!last!'
)

:: unescape - в обратном порядке
set parent=%parent:$_= %
set parent=%parent:$$=$%
echo.
echo the parent is '%parent%'

Пример работы

fullpath='C:\Documents and Settings\All Users\Start Menu\Dollars$and$ many spa_ces\Child'
after preprocessing 'C: Documents$_and$_Settings All$_Users Start$_Menu Dollars$$and$$$_many$_spa_ces Child'
iterating...
parent='' last='C:'
parent='C:' last='Documents$_and$_Settings'
parent='Documents$_and$_Settings' last='All$_Users'
parent='All$_Users' last='Start$_Menu'
parent='Start$_Menu' last='Dollars$$and$$$_many$_spa_ces'
parent='Dollars$$and$$$_many$_spa_ces' last='Child'

PARENT='Dollars$and$ many spa_ces'

Здравствуйте, Кодт, Вы писали:

К>Здравствуйте, wildwind, Вы писали:

К>Чисто на обработке строк, безо всяких экскурсов по файловой системе:

Спасибо! До такого варианта я не додумался, все изгалялся с for /f...
Сейчас вот подумываю, какой вариант выбрать окончательно: ваш, свой или вот такой, дешевый и сердитый:

@echo off
pushd ..
set s=%cd%
set s=%s:*\=%
set s=%s:*\=%
set s=%s:*\=%
set s=%s:*\=%
:: Повторить N раз... :)
popd

echo the parent is '%s%'

Здравствуйте, wildwind, Вы писали:

W>set s=%s:*\=%

Ух ты, я о таком не подозревал!
А для повторения — делаем очень просто

:repeat
set next=%now:*\=%
if "%now%"=="%next%" goto done
set now=%next%
goto repeat
:done
:: здесь now содержит последний токен

А вот чтобы предпоследний токен получить... это я сходу не знаю как.

Здравствуйте, Кодт, Вы писали:

К>А для повторения — делаем очень просто

К>:repeat
К>set next=%now:*\=%
К>if "%now%"=="%next%" goto done
К>set now=%next%
К>goto repeat
К>:done
К>:: здесь now содержит последний токен
К>

Громоздко как-то... Так, что ли:

set s=%cd%
for /l %%I in (0,1,20) do set s=!s:*\=!

Здравствуйте, wildwind, Вы писали:

W>Громоздко как-то... Так, что ли:

set s=%cd%
W>for /l %%I in (0,1,20) do set s=!s:*\=!

Так, конечно, компактнее... но откуда такая уверенность, что глубина вложенных папок не превосходит 20?

Здравствуйте, Кодт, Вы писали:

К>Так, конечно, компактнее... но откуда такая уверенность, что глубина вложенных папок не превосходит 20?

Что-то мне подсказывает... что для реальных применений оно так.
Но для верности можно увеличить до 128 (MAX_PATH=260). Жалка нэту, да!

Здравствуйте, Кодт, Вы писали:

Извините что я вмешиваю в ваш междусобойчик, но таки вот так не будет ли проще

@echo off
setlocal enabledelayedexpansion
set name=%cd%
cd ..
@echo !name:%cd%\=!
endlocal

Здравствуйте, Young, Вы писали:

Y>Извините что я вмешиваю в ваш междусобойчик, но таки вот так не будет ли проще

Супер! Кажется это то что надо. И вроде никаких подводных камней нет. Обрабатывает даже папки первого уровня.
Большое спасибо!

Здравствуйте, Young, Вы писали:

Y>Извините что я вмешиваю в ваш междусобойчик, но таки вот так не будет ли проще

Y>@echo off
Y>setlocal enabledelayedexpansion
Y>set name=%cd%
Y>cd ..
Y>@echo !name:%cd%\=!
Y>endlocal

Осталось только эскейпить знаки = ~ ! потому что они могут попасться в пути и разрушить синтаксическую корректность макроподстановки.